跳ね込むの日記 - hanekomu's Perl blog

global:
  log:
    level: error
plugins:
  - module: Subscription::Config
    config:
      feed:
        - script:///home/gr/plagger/feeds/engrish_com-recent_discoveries.pl
  - module: CustomFeed::Script
  - module: Publish::Feed
    config:
      dir: /path/to/htdocs/feeds
      filename: engrish_com-recent_discoveries.rss
      format: RSS

#!/usr/bin/env perl

use strict;
use warnings;
use Web::Scraper;
use URI;
use YAML;
use DateTime;
use DateTime::Format::W3CDTF;

my $uri = URI->new('http://engrish.com/recent.php');

my $s = scraper {
    process '//a[contains(@href,"recent_detail.php")]',
        'entries[]' => {
            link  => '@href',
            title => scraper {
                process 'img', title => '@alt';
                result 'title';
            },
        }
};

my $feed = $s->scrape($uri);
splice @{ $feed->{entries} || [] }, 10;

$feed->{title} = 'Engrish.com Recent Discoveries';
$feed->{link} = $uri->as_string;

for my $entry (@{ $feed->{entries} }) {

    # extract the date from the 'link' key; it looks something like
    #
    # recent_detail.php?imagename=foobar.jpg&category=Clothing&date=2007-09-12

    if ($entry->{link} =~ /date=(\d{4})-(\d{2})-(\d{2})/) {
        my $date = DateTime->new(
            year  => $1,
            month => $2,
            day   => $3,
        );
        $entry->{date} = DateTime::Format::W3CDTF->format_datetime($date);
    }

    if ($entry->{link} =~ /imagename=(.*?)&/) {
        $entry->{body} = qq!<img src="http://engrish.com/image/engrish/$1" />!;
    }

    $entry->{link} = 'http://engrish.com/' . $entry->{link};
}

print Dump $feed;